PROCESS Model 14 Moderated Mediation:

Running and Interpreting Model 14 of Hayes' PROCESS-macro (Version 3)

Arndt Regorz, Dipl. Kfm. & M.Sc. Psychologie, 05/23/2021

This is the companion webpage to the video tutorial about PROCESS model 14, a moderated mediation with a moderated b-path. Here you can find a syntax example for running PROCESS model 14 by SPSS syntax and a syntax example for checking the regression assumptions with SPSS.

IMPORTANT INFORMATION

During the time since shooting this video I have come to the conclusion that in almost all cases you should use PROCESS model 15 instead of model 14 and here's why:
Most of the time we do not really know whether we have a moderation of the direct effect c' or not. We have a theory about a conditional indirect effect but rarely do we have a full theory about the direct effect. But if we use model 14 and we do, in fact, have a moderated direct effect c', then we can get seriously biased results for the interaction of the b-path and for the index of moderated mediation. For that reason I recommend using model 15 instead - if there is no moderation for the direct effect c' then model 15 will show that, too, so you are safe either way. Here you can find my video about model 15: https://www.youtube.com/watch?v=86SwUJzWhe8

1. Video tutorial

(Note: When you click on this video you are using a service offered by YouTube.)

2. PROCESS syntax for model 14 (example)

*This is the syntax example from the video tutorial for model 14.
*based on P R O C E S S version 3.4:.

process y=Y /x=X /m=MED /w= MOD /model=14 /cov=COVA /modelbt=1 /hc=4 /center=2 /plot=1 /moments=1 /jn=1 /decimals=F10.3 /seed=123456.

3. Assumptions check with SPSS syntax (example)

*Syntax example to check regression assumptions for P R O C E S S model 14.
*In this example one covariate (COVA) is used and X and MED are continuous!
*No robust standard errors are used so the p-values could be slightly.
*different from the P R O C E S S output.

*This is only an instructional example. No warranty of any kind is given for its correctness.

*If you use this syntax please make sure that you get the same regression weights.
*as by running P R O C E S S. Otherwise you have not replicated P R O C E S S with SPSS syntax.
*and can not use the results to check the regression assumptions.

*Mean centering of MED and MOD.
*(shoud be used only for continous variables).

AGGREGATE
/OUTFILE=* MODE=ADDVARIABLES OVERWRITE = YES
/BREAK=
/MED_mean=MEAN(MED).

AGGREGATE
/OUTFILE=* MODE=ADDVARIABLES OVERWRITE = YES
/BREAK=
/MOD_mean=MEAN(MOD).

COMPUTE MED_c = MED - MED_mean.
COMPUTE MOD_c = MOD - MOD_mean.
EXECUTE.

*Calculating the interaction MOD-MED.
COMPUTE Int = MED_c * MOD_c.
EXECUTE.

*Model for the a-path.

REGRESSION
/MISSING LISTWISE
/STATISTICS COEFF OUTS R ANOVA COLLIN TOL
/CRITERIA=PIN(.05) POUT(.10)
/NOORIGIN
/DEPENDENT MED_c
/METHOD=ENTER X COVA
/PARTIALPLOT ALL
/SCATTERPLOT=(*SRESID ,*ZPRED)
/RESIDUALS DURBIN HISTOGRAM(ZRESID) NORMPROB(ZRESID)
/CASEWISE PLOT(ZRESID) OUTLIERS(3).

*Model for the b-path and c'-path.

REGRESSION
/MISSING LISTWISE
/STATISTICS COEFF OUTS R ANOVA COLLIN TOL
/CRITERIA=PIN(.05) POUT(.10)
/NOORIGIN
/DEPENDENT Y
/METHOD=ENTER X COVA MED_c MOD_c Int
/PARTIALPLOT ALL
/SCATTERPLOT=(*SRESID ,*ZPRED)
/RESIDUALS DURBIN HISTOGRAM(ZRESID) NORMPROB(ZRESID)
/CASEWISE PLOT(ZRESID) OUTLIERS(3).

4. References

Hayes, A. F. (2017). Introduction to mediation, moderation, and conditional process analysis: A regression-based approach. New York, NY: Guilford Publications.

Hayes, A. F. (n.d.). PROCESS (Computer Software). Retrieved from https://www.processmacro.org/download.html